Przykład nr 1

Koniec tego teoretyzowania :-). W tej "lekcji" zrobimy coś praktycznego. Przykład, którym się posłużę, będzie prosił użytkownika o wskazanie punktu, a następnie w miejscu wskazanym wstawiony zostanie krzyżyk opisujący współrzędne, X i Y.

Kod rysujący taki znaczek wyglądałby następująco:

;

(vl-load-com)
(setq *ZCApp* (vlax-get-zwcad-object))
(setq *ActiveDocument* (vla-get-activedocument *ZCApp*))
(setq *MSpace* (vla-get-modelspace *ActiveDocument*))
(defun FullGetpoint (startPoint promp DefVal / ans outVal )
(if startPoint
(setq ans(vl-catch-all-apply 'getpoint (list startPoint promp ))) ; Wskaż punkt, z uwzględnieniem punku początkowego
(setq ans(vl-catch-all-apply 'getpoint (list promp ))) ; Wskaż punkt
)
(if (not(vl-catch-all-error-p ans)) ;warunek sprawdzający czy nie wystąpił błąd we wskazywaniu punku
(progn
(if ans ;Warunek sprawdzający czy został wskazany prawidłowy punkt
(setq outVal ans) ; Zwrócona zostanie lista współrzędnych wskazanego punktu
(setq outVal DefVal) ; Zwrócona zostanie wartość domyślna
)
)
(setq outVal nil) ; zwrócona zostanie pusta wartość
)
outVal
)

(defun C:Krzyz ( / P0 P0v Wysokosc TextX TextXEnt TextY TextYEnt TextBBox textwidth)
(setq P0 (FullGetpoint nil "Wskaż punkt" nil))
(setq P0v (vlax-3d-point P0))
(setq Wysokosc 5)
(if P0
(progn
(setq TextX (vla-addtext *MSpace* (rtos (car P0) 2 2) P0v Wysokosc)) ;dodaje tekst
(setq TextXEnt(entget(vlax-vla-object->ename TextX)))
(setq TextBBox (textbox TextXEnt))
(setq textwidth (caar(cdr TextBBox ))) ;Oblicza szerokość tekstu
(vlax-invoke-method TextX 'Move P0v (vlax-3d-point(list (+ (car P0) (* 0.2 Wysokosc )) (+ (cadr P0) (* 0.2 Wysokosc )) (+ (caddr P0) (* 0.1 Wysokosc ))))) ; Przesuwa punkt
(vla-addline *MSpace* (vlax-3d-point (list (- (car P0) (+ textwidth (* 0.2 Wysokosc ))) (cadr P0) (caddr P0))) ;Tworzy linię
(vlax-3d-point (list (+ (car P0) (+ textwidth (* 0.2 Wysokosc ))) (cadr P0) (caddr P0))))
(vla-addline *MSpace* (vlax-3d-point (list (car P0) (+ (cadr P0) (+ textwidth (* 0.2 Wysokosc ))) (caddr P0)))
(vlax-3d-point (list (car P0) (- (cadr P0) (+ textwidth (* 0.2 Wysokosc ))) (caddr P0))))
(setq TextY (vla-addtext *MSpace* (rtos (cadr P0) 2 2) P0v Wysokosc))
(vlax-invoke-method TextY 'Move P0v (vlax-3d-point(list (+ (car P0) (* 0.2 Wysokosc )) (+ (cadr P0) (* 0.2 Wysokosc )) (+ (caddr P0) (* 0.1 Wysokosc )))))
(vlax-invoke-method TextY 'Rotate P0v (/ pi -2.0))
)
)
(command "regen")
(print )
)

Linie 1-4 są podstawą, najlepiej zapisać sobie to w szablonie i każdy tworzony plik lispa zaczynać od tych linii.
Linie 5-20 to funkcja prosząca użytkownika o wskazanie punktu. Zawiera obsługę sytuacji wyjątkowych jak wciśnięcie klawisza [ESC]. Jeśli użytkownik wciśnie [ENTER] zostanie zwrócona domyślna wartość (trzeci parametr wywołania funkcji).
Linie 21 - 41 Główna funkcja rysująca znacznik
Linia 27 Tworzony jest nowy obiekt - tekst jednowierszowy.
(rtos (car P0) 2 2) pobiera współrzędną X wskazanego punktu. Jest to liczba. Natomiast do tworzenia tekstu potrzebna jest nam zmienna typu tekst. Konwersji liczby rzeczywistej na tekst można dokonać funkcją rtos. Jej parametrami wywołania są trzy liczby: Pierwsza to wartość jaką chcemy zamienić. Druga to system w którym chcemy wyświetlić, gdzie 2 oznacza system dziesiętny. Trzecia to ilość miejsc po przecinku, do których chcemy zaokrąglić. Po takiej zamianie mamy wartość, która będzie wyświetlana, kolejne parametry to współrzędne punktu wstawienia takiego tekstu oraz wysokość tekstu.
Wielkość znaku krzyża, czyli długości linii tworzących znak możemy ustawić na stałe. Na potrzeby tego przykładu postanowiłem że długość tych linii zależna będzie od szerokości tekstu, czyli pokreślony zostanie cały napis, niezależnie od tego, ile znaków będzie miał tekst. Szerokość tekstu możemy poznać na dwa sposoby. Pierwszy sposób dotyczy jedynie tekstów jednowierszowych i jest to funkcje textbox. Inny to GetBoundingBox, ale o niej porozmawiamy innym razem
Linia 29 "mierzy" szerokość tekstu jednowierszowego. Jej parametrem jest nazwa obiektu (zwracana przez entget). Funkcja zwraca dwuelementową listę, na podstawie której, możliwe jest określenie wysokości i szerokości tekstu.
Linia 28 Zmienia teksty typu obiekt na nazwę obiektu, która jest potrzebna do funkcji textbox
Linia 31 Gdyby tekst leżał dokładnie na linii czyli we współrzędnych wskazanych przez użytkownika byłoby to mało czytelne, dlatego podniesiemy nasz napis odrobinę, a dokładnie to o 1/5 wysokości napisu i przesuniemy go w prawo.
Linia 32, 33 Tworzą linie, których współrzędne początku i końca są odsunięte w poszczególnych kierunkach o szerokość tekstu.
Linie 34-41 Dodają ostatni tekst, określający współrzędną y. Tekst ten również jest przesuwany, żeby nie pokrywać się z linią a następnie obracany jest o 90 stopni, aby unaocznić że dotyczy to współrzędnej y.

Spis treści

DCL